ILOGICSボードではILOGICSが開発した内蔵コマンドを使用できます。別途ライブラリをインストールせず、ILOGICSボードを選択するだけで使用できます。

1. ILOGICSボードパッケージをインストールします。（Arduino SDK）
2. Arduino IDEのツール → ボードで使用するボードを選択します。
3. 内蔵コマンドを使用します。

例に記載された入出力アドレスは製品によって異なります。使用するILOGICS製品のボード定義を選択し、その製品のピンマップでアドレスを確認してください。

カテゴリ別に探す

• デジタル入力フィルタ · エッジ検出・範囲変換 · PLCタイマ · コールバックタイマ
• カウンタ・データバッファ · 高速カウンタ · アナログ入力 · 温度入力
• アナログ出力・PWM · PID制御 · 表示器・RTC
• デバッグ・Watchdog · 通信

IdigitalRead()は短時間に繰り返しサンプリングする方式で、Ibounce()はmillis()を基準に入力が安定した時間を確認する方式です。機械式スイッチには通常Ibounce()が適しています。

idは各エッジ検出状態を区別します。異なる入力に同じidを使うと状態が混在する場合があります。

次の例では、MPAINO-8A8R(T)の最初の入力0と出力64を使用します。

bool lampState = false;
 
void setup() {}
 
void loop() {
  bool button = Ibounce(0, 30);
  Ialt(button, lampState);
  digitalWrite(64, lampState); // MPAINOの最初のデジタル出力の例
}

PLCスタイルタイマはdelay()のようにプログラムを停止しません。代わりにloop()が繰り返されるたびに継続的に呼び出してください。異なるタイマに同じidを重複使用しないでください。

次の例では、MPAINO-8A8R(T)の最初の入力0と出力64を使用します。

void setup() {}
 
void loop() {
  bool run = Ibounce(0, 30);
  bool delayedOutput = Iton(0, run, 1000);
  digitalWrite(64, delayedOutput);
}

コールバック関数は割り込み内で実行されます。コールバックではフラグや短いカウントだけを変更し、delay()、Serial出力、I²C、SPI、長い計算を使用しないでください。

volatile bool taskFlag = false;
 
void onTimer() {
  taskFlag = true;
}
 
void setup() {
  ItimerSet(100, onTimer);
  ItimerStart();
}
 
void loop() {
  if (taskFlag) {
    taskFlag = false;
    // 時間のかかる実際の処理はloop()で実行します。
  }
}

カウンタコマンドはloop()で継続的に呼び出します。idは他のカウンタと重複しないように割り当てます。

MPAINOでは装着したアナログ入力モジュールとDIPスイッチの電圧・電流範囲を先に確認します。サンプリング速度を上げると応答は速くなりますが、ノイズや測定特性が変わる場合があります。

void setup() {
  Serial.begin(115200);
  analogReadInit(IANALOG_SPS_64);
}
 
void loop() {
  int32_t raw = analogReadAvg(0, 8);
  float value = Iscalef(raw, 0.0, 32767.0, 0.0, 100.0);
  Serial.println(value);
}

NTCとPT100はセンサ種類と入力回路が異なります。相互に置き換えて使用せず、選択した製品に該当する入力機能があるか確認してください。

PWM、高速パルス、analogWrite()、コールバックタイマは同じハードウェアタイマを共有する場合があります。複数の機能を組み合わせるときは、該当製品のタイマ対応表を確認してください。

void setup() {
  IpidSet(0, 2.0, 0.5, 0.1, 100, 0, 100);
}
 
void loop() {
  float pv = ntcReadf(0);
  float output = IpidRun(0, pv, 50.0);
  IanalogWritef(0, 0.0, 100.0, output);
}

PID出力は計算値であり、安全装置ではありません。センサ断線、過温度、出力固着、非常停止は別の安全回路で処理してください。

表示装置とRTCは、それぞれのBeginコマンドを先に呼び出します。I²Cアドレス、接続ピン、他の機能との共有有無を確認してください。

Watchdogを有効にした後、WDT()の呼び出しが遅れるとボードが再起動します。通信待ちと長いループの最悪実行時間を先に確認してください。

現在、タイマ外部クロック方式の専用高速カウンタに対応する製品はMPINO-8A8RとMPINO-16A8R8Tです。他の製品では製品別の割り込み入力を確認し、attachInterrupt()方式を使用します。

void setup() {
  ImodbusRTUMem(128, 64);
  ImodbusRTUAdr(0, 0);
  ImodbusRTUInit(Serial2, 1, 9600);
}
 
void loop() {
  ImodbusRTU();
}

RS-232、RS-485、UARTのSerial番号は製品によって異なる場合があります。通信前にポートの役割、電気規格、ボーレート、局番、終端抵抗、DIPスイッチ設定を確認してください。

以下の例ではMPAINOの最初のデジタル入力0と最初のデジタル出力64を使用します。MPINOでは選択したモデルの実際のArduinoピン番号に変更してください。

const uint8_t inputChannel = 0;
const uint8_t outputChannel = 64;
 
void setup() {}
 
void loop() {
  bool stableInput = Ibounce(inputChannel, 30);
  bool delayedOutput = Iton(0, stableInput, 1000);
  digitalWrite(outputChannel, delayedOutput);
}

• コマンドが見つからない： ILOGICSボードパッケージのインストールと製品ボードの選択を確認します。
• 入出力が反応しない： MPINOのピン番号とMPAINOの論理チャネルを混同していないか確認します。
• タイマ・カウンタが停止する： loop()でコマンドを継続的に呼び出しているか、同じidを重複使用していないか確認します。
• PWM周波数がおかしい： 同じハードウェアタイマを別のPWM・パルス・コールバック機能が使用していないか確認します。
• アナログ値が異なる： 電圧・電流・NTC・PT100のDIPスイッチ、チャネル、サンプリング速度を確認します。
• 通信できない： Serialポート、RS-232/RS-485方式、ボーレート、局番、パリティ、配線を確認します。
• ボードが繰り返し再起動する： Watchdogの制限時間より長くかかるコードがないか確認します。

• 従来の#include <ILIB.h>、tempRead()、Ipt100Read()の例を現在の内蔵コマンドと混用しないでください。
• 電源や配線を変更するときは機器の電源を切り、極性、COM、入力電圧、負荷電源を確認します。
• リレー出力とトランジスタ出力の電気的特性および許容電流を区別してください。
• プログラム出力だけを非常停止や過電流保護の手段として使用しないでください。
• 製品別のピンマップ、電気仕様、対応タイマは該当する製品説明書を最終基準として確認します。

• 製品選択ガイド
• MPINOの製品特長と使用の流れ
• MPAINOのモジュール構成と論理チャネル
• Arduino IDEで初めて使う
• はじめての配線と入出力確認
• 安全および設置上の注意事項